SQLServer2016の行レベルのセキュリティ

以下は、RLSを実装する方法の例です。

ステップ1：次のコードを実行して、データベース RowFilterを作成します と2人のユーザーがテストします：

CREATE DATABASE RowFilter;
GO
USE RowFilter;
GO
CREATE USER userBrian WITHOUT LOGIN;
CREATE USER userJames WITHOUT LOGIN;
GO

手順2：次のコードを実行して、例を含むテーブルを作成し、新しいユーザーにSELECT権限を付与します。

CREATE TABLE dbo.SalesFigures (
[userCode] NVARCHAR(10),
[sales] MONEY)
GO
INSERT  INTO dbo.SalesFigures
VALUES ('userBrian',100), ('userJames',250), ('userBrian',350)
GO
GRANT SELECT ON dbo.SalesFigures TO userBrian
GRANT SELECT ON dbo.SalesFigures TO userJames
GO

手順3：次のコードを実行して、フィルター述語関数を追加します。

CREATE FUNCTION dbo.rowLevelPredicate (@userCode as sysname)
RETURNS TABLE
WITH SCHEMABINDING
AS
RETURN SELECT 1 AS rowLevelPredicateResult
WHERE @userCode = USER_NAME();
GO

ステップ4：次のコードを実行して、テーブルにフィルター述語を追加します dbo.SalesFigures ：

CREATE SECURITY POLICY UserFilter
ADD FILTER PREDICATE dbo.rowLevelPredicate(userCode)
ON dbo.SalesFigures
WITH (STATE = ON);
GO

ステップ5：次のコードを実行して、ステップ2で追加されたユーザーで結果をテストします：

EXECUTE AS USER = 'userBrian';
SELECT * FROM dbo.SalesFigures;
REVERT;
GO

このコードは、以下に示すように2つの行を返します。

（/article/uploadfiles/202207/2022070812111051.png）

EXECUTE AS USER = 'userJames';
SELECT * FROM dbo.SalesFigures;
REVERT;
GO

このコードは、次のように1行を返します。

（/article/uploadfiles/202207/2022070812111024.png）