基準に基づいて Excel で一意のリストを作成する (9 つの方法)

Microsoft Excel では、複数の条件の下で一意のリストを作成する方法がいくつかあります。一意のリストは通常​​、テーブルから重複を削除するために用意されています。この記事では、さまざまな方法を使用して、いくつかの条件に基づいて一意のリストを生成する方法を学びます.

この記事の準備に使用した Excel ワークブックをダウンロードできます。

基準に基づいて Excel で一意のリストを作成する 9 つの方法

1.複数の列基準を持つ一意の行のリストを作成する

次の図では、左側のテーブルにいくつかのランダムなスポーツ名、参加者、年齢が表示されています。右側の別のテーブルは、一意の値のみに基づいてデータを抽出する出力テーブルです。たとえば、一意の参加者の名前と年齢だけを知りたいとします。

UNIQUE を使用します ここでは、範囲または配列から一意の値を返す関数を使用します。この関数の一般的な式は次のとおりです:

=UNIQUE(array, [by_col], [exactly_once])

ユニーク 関数は Excel 365 でのみ使用できます 、最後の 3 つのセクションで、他の従来の機能を組み合わせた代替方法も示してから、結論に進みます。

したがって、セル F5 で必要な関数 になります:

=UNIQUE(B5:C13,FALSE,FALSE)

Enter を押した後 の場合、関数は一意の名前と対応する参加者の年齢を含む配列を返します。

続きを読む:Excel で条件に基づいてリストを生成する方法 (4 つの方法)

2.アルファベット順にソートされた一意の値のリストを取得

SORT を使用して、アルファベット順に並べ替えられた一意の値を取得することもできます 関数。ソート順を昇順 (A to Z) で表す または降順 (Z から A) 基準に従って、参加者の名前をイニシャルに基づいて並べ替えることができます。

出力のセル E5 、 SORT を使用した必要な数式 そしてユニーク 関数は次のようになります:

=SORT(UNIQUE(B5:C13,FALSE,FALSE),,1)

Enter を押した後 、関数は A から Z のアルファベット順に並べ替えられた配列を返します .

続きを読む: Excel でアルファベット順のリストを作成する方法 (3 つの方法)

3. 1 つのセルに連結された一意の値のリストを作成

2 つの列から一意のデータを抽出し、値を結合して 1 つの列に連結された値を返すとします。次の図では、固有の名前とそれに対応する年齢が、特定の区切り文字 コンマ (,) を使用して列に一緒に表示されます。 アンパサンド (&) を使用します ここで、2 つの異なる列に沿って値を連結します。

出力 セル F5 に必要な数式 になります:

=UNIQUE(B5:B13&", "&C5:C13)

この数式は、1 つの列に一意の行の配列を返します。

続きを読む: Excel でカンマ区切りのリストを作成する方法 (5 つの方法)

4.条件付きの一意の値のリストを作成する (UNIQUE-FILTER 式)

i. Excel で複数の AND 基準に基づいて一意の値を識別する

このセクションでは、いくつかの基準を追加し、それらの条件に基づいて固有のデータを抽出します。たとえば、水泳のみに参加した 25 歳未満の参加者の一意の名前を知りたいとします。したがって、UNIQUE を組み合わせる必要があります。 とフィルタ

出力 Cell F5 に必要な数式 になります:

=UNIQUE(FILTER(B5:C13,(D5:D13=G9)*(C5:C13<G10)))

Enter を押した後 、数式は、選択した基準に基づいて、一意の名前と対応する年齢の配列を返します。

ii.複数の OR 基準に基づいて一意の値を検索

ここで、屋外スポーツ (水泳とサイクリング) の両方に参加した一意の参加者の名前を知りたいとします。 1 つの列のみから基準を割り当てるため、単純に数値加算を使用して FILTER で 2 つの条件を結合する必要があります。 関数。

セル F5 に必要な式 現在:

=UNIQUE(FILTER(B5:C13,(D5:D13=F11)+(D5:D13=F12)))

Enter を押します 次のスクリーンショットに示すように、抽出された一意のデータがすぐに取得されます。

iii.空白セルを無視して一意の値のリストを取得

データセットには、空白のセルまたは行がいくつか含まれている場合があります。したがって、これらの空白行をスキップしてテーブルから一意のデータを抽出する場合は、比較演算子を使用する必要があります:Not Equal To (<>)

出力に必要な数式 セル F5 になります:

=UNIQUE(FILTER(B5:C13,D5:D13<>""))

Enter を押した後 、数式は、出力テーブルに空白以外の一意の行のみを含む次の配列を返します。

類似の読み物

• Excel で To Do リストを作成する方法 (3 つの簡単な方法)
• Excel でメーリング リストを作成する (2 つの方法)

5. Excel で指定された列の一意の値のリストを検索

いくつかの特定の列のみから一意のデータを抽出したいとします。これらの個別の列をマウス カーソルで選択して、それを UNIQUE の引数として入力することはできません。 関数。したがって、CHOOSE を組み合わせる必要があります。 ここでは UNIQUE で機能します CHOOSE として機能します 関数を使用すると、値のリストからインデックス番号に基づいて、指定された列またはセルの範囲を任意の数選択できます。

データ テーブルから一意の参加者の名前を抽出し、名前 (列 B) からの出力を表示します。 スポーツ名 (列 D) 列のみ。

セル F5 に必要な式 になります:

=UNIQUE(CHOOSE({1,3},B5:B13,C5:C13,D5:D13))

Enter を押した後 の場合、数式は、下の図に示すように、2 つの異なる列から一意の名前と対応するスポーツの名前を返します。

CHOOSE の内部 関数、インデックス番号は 1 と 3 です これは、セルの 1 番目と 3 番目の範囲を値のリストから選択する必要があることを意味します。 UNIQUE 関数は、指定された列のみを考慮し、それらの列から一意のデータを配列で返します。

続きを読む:Excel で番号付きリストを作成する方法 (8 つの方法)

6.一意のリストを作成する際の IFERROR 関数の使用

IFERROR も使用できます UNIQUE の背後にある機能 戻り値にエラーが見つかった場合にカスタマイズされたメッセージを表示する関数。 21 歳未満の一意の参加者の名前を知りたいとします。21 歳未満の参加者のインスタンスは存在しないため、式は #N/A を返す必要があります。 エラー。ただし、このエラーを表示する代わりに、 IFERROR を使用します。 カスタマイズされたメッセージを表示する機能 - 「見つかりません」。

したがって、セル F5 に必要な式は になります:

=IFERROR(UNIQUE(FILTER(B5:C13,C5:C13<=G10)), "Not Found")

Enter を押した後 、次のスクリーンショットに示すように、数式は指定されたメッセージを返します。

7.基準に基づいて一意のリストを抽出する (INDEX-MATCH 式)

UNIQUE を削除します 関数を使用して INDEX の組み合わせを適用します と マッチ 機能。 インデックス 関数は、特定の行と列の交点にあるセルの値または参照を返します。そしてマッチ 関数は、指定された順序で指定された値に一致するアイテムの位置を返します。水泳のみに参加した参加者の一意の名前を知りたいと仮定します。

📌 ステップ 1:

➤ 出力 Cell F5 を選択します 次のように入力します:

=INDEX(B5:B13, MATCH(0, IF($F$12=$D$5:$D$13,COUNTIF($F$4:$F4, $B$5:$B$13), ""), 0))

➤ Enter を押します .

戻り値として最初の一意の名前を取得します。

📌 ステップ 2:

➤ フィル ハンドルを使用する セルを右にドラッグします。

また、参加者の年齢もわかります。

📌 ステップ 3:

➤ セル G5 から 、#N/A になるまで列を埋めます

INDEX-MATCH を使用して、特定の条件に基づいて一意のデータを抽出する方法は次のとおりです。

🔎 数式の仕組み

• COUNTIF($F$4:$F4, $B$5:$B$13): COUNTIF ここの関数は、B5:B13 の範囲で使用可能なすべてのセルを格納およびカウントするために使用されています .関数は次のように返します:

{0;0;0;0;0;0;0;0;0}

• IF($F$12=$D$5:$D$13, COUNTIF($F$4:$F4, $B$5:$B$13), ""): IF 関数は、セル内の指定された条件を検索し、次のように返します:

{0;””;0;””;””;0;””;””;””}

• マッチ 関数は、前のステップで見つかったセルの行番号を返します。
• 最後に INDEX 関数は、これらの行番号に基づいてデータを抽出します。

8.複数の基準に基づいて Excel で独自のリストを作成する

このセクションでは、 INDEX-MATCH 式は、複数の条件が適用されたときに機能します。たとえば、水泳に参加したことのある 25 歳未満の参加者の一意の名前を知りたいとします。

出力 セル F5 に必要な数式 になります:

=IFERROR(INDEX($B$5:$B$13,MATCH(0,COUNTIF(F4:$F$4,$B$5:$B$13)+IF(D5:D13=$G$9,1,0)+IF(C5:C13<$G$10,1,0),0)),"")

Enter を押した後 出力列の新しいセルに自動入力すると、下の図に示すように一意の名前が取得されます。

この式では、2 つの IF で基準を割り当てています。 関数と COUNTIF 関数は、出力セルの配列を抽出する際にこれらの基準を考慮します。前の方法で説明したように、 INDEX-MATCH 式は、その配列に基づいて出力を返します。そして IFERROR ここの関数は、エラーが見つかった場合にカスタマイズされたメッセージを返すために使用されています。

9.条件付きの行と列に沿って複数の一意のリストを作成する

最後の方法では、Excel テーブルを使用して複数の一意のデータ リストを抽出します。次の図では、下部のテーブルに、スポーツの種類に基づいて参加者の一意の名前が表示されます。

テーブルまたはセル範囲に (B5:C13) という名前を付けました スポーツで。列には、SportsName と Name という名前のヘッダーがあります。表のヘッダーはスペースを占有できないことに注意してください。

📌 ステップ 1:

➤ 最初の出力 Cell B16 で必要な数式 になります:

=IFERROR(INDEX(Sports,SMALL(IF(Sports[SportsName]=B$15,ROW(Sports)-4),ROW(1:1)),2),"")

Enter を押した後 、最初の出力値がすぐに返されます。

📌 ステップ 2:

➤ フィル ハンドルを使用 空白のセルが表示されるまで列を埋めます。

📌 ステップ 3:

➤ ここで、出力 (B16:B20) からセルの範囲をコピーします

➤ セル C16 内 、数式 (F) で値を貼り付けます オプション。

サイクリングのみに参加した参加者の一意の名前を含む 2 番目の列が表示されます。

📌 ステップ 4:

➤ 同様に、コピーした値を数式として セル D16 と E16 に再度貼り付けます .

また、スポーツの種類に基づいて、参加者の他の一意の名前をすぐに取得できます。ただし、ここでは単純に Fill Handle を使用できないことを覚えておく必要があります。 列 B の最初の戻り値からセルを右に自動入力します . オートフィル の使用 オプションを使用するとデータが操作され、元の出力を抽出できなくなります。

🔎 数式の仕組み

• IF(Sports[SportsName]=B$15, 行 (スポーツ)-4): 関数のこの部分は、セル B15 のヘッダーで指定された特定の条件を検索します。 関数は次のように返します:

{1;FALSE;FALSE;4;FALSE;FALSE;7;8;FALSE}

• SMALL(IF(Sports[SportsName]=B$15, ROW(Sports)-4), ROW(1:1)): 小さい 関数は、前の出力と セル C16 から最小の数値を抽出します 、「1」です .
• インデックス 関数は SMALL で指定された行番号に基づいて名前を引き出します 関数。
• IFERROR 関数は、エラー出力が見つかった場合に空白セルを表示するために使用されています。
• この組み合わせ式では、数値 「4」 「ROW(Sports)-4」の部分 は、プライマリ データ テーブルのヘッダーの行番号です。

結びの言葉

上記のすべての方法が、データ テーブルから一意の値のリストを作成する際に、Excel スプレッドシートでより効果的に適用できるようになることを願っています。ご質問やご意見がございましたら、コメント欄でお知らせください。または、この Web サイトで Excel 関数に関連する他の記事を確認することもできます。

こちらもご覧ください

• Excel で箇条書きリストを作成する方法 (9 つの方法)
• Excel のセル内にリストを作成する (3 つの簡単な方法)
• Excel で価格表を作成する方法 (ステップ バイ ステップのガイドライン)