MyDefragでハードディスクを完全に最適化する方法｜スクリプトによるゾーン設定ガイド

ハードディスクドライブ（HDD）の主要な構成要素は、回転するプラッターと、その表面からデータを読み書きするヘッドです。物理の法則が示すように、円盤状のプラッターの外側部分ほど線形速度が速くなります。また、データがディスク表面に散らばっていると、パフォーマンスが低下するという問題もあります。

MyDefragは現在開発が終了しているソフトウェアですが、自分の望む通りの方法でハードディスクを精密に最適化できる唯一のプログラムとして、今なお現役で使えます。他のデフラグツールと同様に、ファイルの断片を再編成してひとまとめにすることで、データの分散によるパフォーマンス低下を解消します。さらに「ゾーン」という概念を導入でき、重要なファイルをHDD表面の高速な外側エリアに配置することも可能です。必要なのは、シンプルなスクリプトで「何をどこに置くか」を指示することだけです。

MyDefragの入手とインストール

残念ながら、MyDefragは現在サポートが終了しており、公式サイトも閉鎖されています。しかし、FileHippoやMajorGeeksなどの有名なソフトウェア配布サイトから、今でも入手可能です。

最終バージョンとなるMyDefrag 4.3.1をダウンロードしてインストールしましょう。インストール中は基本的にデフォルト設定のまま進め、「Select and activate the MyDefrag ScreenSaver」のチェックだけは外しておいてください。

新しいスクリプトを作成する

MyDefragの動作は、GUIやコマンドラインオプションではなく、シンプルなスクリプトによって制御します。インストールディレクトリには、そのための「scripts」サブフォルダが用意されています。

このフォルダ内で右クリックし、空のTXTファイルを新規作成します。ファイル名は自由ですが、拡張子はMyDefragスクリプトの標準である「MyD」に変更してください。その後、お好みのテキストエディタで開きます。

スクリプトの基本構造

ここでは既存のスクリプトをベースに、ゲーム用途で埋まったハードディスクを最適化するスクリプトを作成します。パフォーマンスへの影響が大きいファイルをディスクの高速な領域へ配置し、重要度の低いデータやアクセス頻度の少ないファイルは反対側へ追いやる構成です。

スクリプトの冒頭部分は以下のように記述します。すべてのパラメータとコマンドは、必ず個別の行に配置してください。また、コード内では「//」で始まるコメントを使い、わかりにくい箇所を補足していきます。

Title("スクリプトのタイトル")
Description("スクリプトの簡単な説明")
WriteLogfile("MyDefrag.log","LogHeader")
VolumeSelect
CommandlineVolumes()
VolumeActions
AppendLogfile("MyDefrag.log","LogBefore")

最初のゾーンを設定する

HDDの表面をゾーンに分割することで、MyDefragは特定のファイルやフォルダを、読み書き速度の良い領域にも悪い領域にも自由に配置できるようになります。

ゾーンを設定するには、そこに含める対象を選択します：

// ゾーン1：重要度の低い低速ファイル
FileSelect // 対象ファイルを選択
  !include "file_list.txt"! // file_list.txtで定義されたファイルを選択
FileActions // MyDefragが実行する処理
  MoveToEndOfDisk() // 重要度が低いため、HDDの低速な領域へ移動
  AddGap(ZoneEnd + VolumeFree * 0.1) // 次のゾーンとの間に0.1%分のギャップを確保
FileEnd // このゾーンの選択を終了

さらにゾーンを追加する

ゾーンを一切設定しない場合、MyDefragは他の一般的なデフラグツールと同様に、単にファイルを断片化なくまとめることしかできません。それではこのツールを使う本来のメリットを活かせません。

以下のように、複数のゾーンを順番に定義していきます：

// ゾーン2：ディレクトリをまとめて、HDD内容の一覧表示を高速化（記法は前と同じ）
FileSelect
  Directory(yes) // ファイルではなくディレクトリを選択
FileActions
  SortByName(Ascending) // アルファベット順にソート
  AddGap(ZoneEnd + VolumeFree * 0.05)
FileEnd

// ゾーン3：代表的なゲーム関連ファイル群（ゲーム起動の高速化）
FileSelect
Filename("*.exe")
OR Filename("*.dll")
OR Filename("*.ini")
OR Filename("*.conf")
OR Filename("*.cfg")
OR Filename("*.bat")
OR Filename("*.ico")
FileActions
  SortByName(Ascending)
  AddGap(ZoneEnd + VolumeFree * 0.1)
FileEnd

// ゾーン4：MFTなどの特殊なNTFSシステムファイルを、最重要ファイルの直後に配置
FileSelect
  SelectNtfsSystemFiles(yes)
FileActions
  PlaceNtfsSystemFiles(Ascending,MftSize * 0.01) // NTFSシステムファイルを移動し、MFTサイズを0.01%に設定
  AddGap(ZoneEnd + VolumeFree * 0.01)
FileEnd

// ゾーン5：最近アクセスしたファイル（直近プレイしたゲームのパフォーマンス向上）
FileSelect
  LastAccessEnabled(yes) and LastAccess(60 days ago,now)
FileActions
  SortByName(Ascending)
  AddGap(ZoneEnd + VolumeFree * 0.3)
FileEnd

// ゾーン6：その他すべてのファイル
FileSelect
  all
FileActions
  SortByName(Ascending)
  AddGap(ZoneEnd + VolumeFree)
FileEnd

完成版スクリプト

以下が完成版のスクリプト全文です。そのままコピー＆ペーストして、自分の環境に合わせて自由に調整してください。

Title("Games HDD Monthly Optimization")
Description("一時ファイル・ダウンロードファイル・重要度の低いゲーム関連ファイルやフォルダをディスク末尾へ移動し、高速な領域を重要なデータのために確保することで、ゲーム用HDDを最適化します。")

// ログファイルにヘッダーを書き込む。「LogHeader」文字列の定義は「Settings.MyD」ファイルを参照。
WriteLogfile("MyDefrag.log","LogHeader")

// ボリュームを1つずつ選択して処理する。
VolumeSelect
  CommandlineVolumes()
VolumeActions

// 処理前の統計情報をログに書き込む。「LogBefore」の定義は「Settings.MyD」を参照。
  AppendLogfile("MyDefrag.log","LogBefore")

// ゾーン1：重要度の低い一時ファイル・超大容量ファイルをディスク末尾へ配置。
  FileSelect
    !include "file_list.txt"!
  FileActions
    MoveToEndOfDisk()
    AddGap(ZoneEnd + VolumeFree * 0.1)
  FileEnd

// ゾーン2：ディレクトリ。
  FileSelect
    Directory(yes)
  FileActions
    SortByName(Ascending)
    AddGap(ZoneEnd + VolumeFree * 0.05)
  FileEnd

// ゾーン3：主要なゲームファイル（ゲーム起動の高速化）。
  FileSelect
    Filename("*.exe")
	OR Filename("*.dll")
	OR Filename("*.ini")
	OR Filename("*.conf")
	OR Filename("*.cfg")
	OR Filename("*.BAT")
	OR Filename("*.ico")
  FileActions
    SortByName(Ascending)
    AddGap(ZoneEnd + VolumeFree * 0.1)
  FileEnd

// ゾーン4：MFTおよびその他の特殊なNTFSファイルを配置。
  FileSelect
    SelectNtfsSystemFiles(yes)
  FileActions
    PlaceNtfsSystemFiles(Ascending,MftSize * 0.01)
    AddGap(ZoneEnd + VolumeFree * 0.01)
  FileEnd

// ゾーン5：最近アクセスしたファイル（直近プレイしたゲームのパフォーマンス向上）。
  FileSelect
    LastAccessEnabled(yes) and LastAccess(60 days ago,now)
  FileActions
    SortByName(Ascending)
    AddGap(ZoneEnd + VolumeFree * 0.3)
  FileEnd

// ゾーン6：その他すべてのファイル。
  FileSelect
    all
  FileActions
    SortByName(Ascending)
    AddGap(ZoneEnd + VolumeFree)
  FileEnd

// 処理後の統計情報をログに書き込む。「LogAfter」の定義は「Settings.MyD」を参照。
  AppendLogfile("MyDefrag.log","LogAfter")

VolumeEnd

// ログファイルにフッターを書き込む。「LogFooter」の定義は「Settings.MyD」を参照。
AppendLogfile("MyDefrag.log","LogFooter")

低優先度ファイルリストを作成する

スクリプト内で、TXT形式の「低優先度ファイルリスト」を参照するよう指定したのを覚えていますか？　次はそのファイルを作成します。

scriptsフォルダ内で右クリックし、空のTXTファイルを新規作成します。ファイル名はスクリプト本体で指定したものと同じ「file_list.txt」にしてください。

以下はそのままコピーして使えるサンプルリストです。ディレクトリ名やファイル名は、自分が重要視しないものに書き換えましょう。

  DirectoryName("Game_I_never_play_after_installing")
    OR DirectoryName("Another_game_I_keep_but_rarely_play")
    OR DirectoryName("Game_that_takes_up_almost_half_the_HDD")
    OR Filename("vc_redist.x64.exe")
    OR Filename("vcredist_x64.exe")
    OR Filename("vcredist_x64*.exe")
    OR Filename("*.iso")
    OR Filename("*.isz")
    OR Filename("*.mdf")
    OR Filename("*.cdi")
    OR Filename("*.pdf")
    OR Filename("*.bik")
    OR Filename("*.avi")
    OR Filename("*.wmv")
    OR Filename("*.bk2")
    OR Filename("*.mp4")
    OR Filename("*.rar")
    OR Filename("*.zip")
    OR Filename("*.7z")
    OR Filename("*.7z.*")

スクリプトを実行する

デフラグのロジックを定義する2つのファイルが揃ったら、いよいよ実行です！　MyDefragを起動すると、タイプミスなどがなければ、作成したスクリプトがプログラムのスクリプトリストに表示されるはずです。

「Select a script」リストから自分のスクリプトを選択します。続けて、MyDefragの案内に従い、2番目のリストからスクリプトのルールを適用したいディスクを1つ以上選びます。「Run」をクリックしたら、あとは処理が完了するまで待つだけです。所要時間は数時間、テラバイト級の大容量HDDなら数日かかることもあります。

これで完了です。ハードディスクを自分の意図どおりにデフラグし、最適化できました。これまでより速く、快適に動作するはずです。

関連記事：

• ドライブをデフラグすると実際には何が起こるのか？
• Windows 10のハードドライブ性能を向上させる5つのツール
• Windowsのコンテキストメニューからハードドライブをデフラグする方法